@echo off
title Instalador Acesso Remoto - Prosperarti

REM ============================================================
REM  Acesso-Prosperarti.bat
REM  Baixa e executa o instalador do RustDesk com a configuracao
REM  da Prosperarti. Faz auto-elevacao para administrador.
REM ============================================================

REM Verifica se ja esta rodando como administrador
net session >nul 2>&1
if %errorlevel% neq 0 (
    echo Solicitando permissao de administrador...
    powershell -Command "Start-Process -FilePath '%~f0' -Verb RunAs"
    exit /b
)

cls
echo.
echo ================================================
echo    Instalador Acesso Remoto - Prosperarti
echo ================================================
echo.
echo  Este processo leva entre 1 e 3 minutos.
echo  Por favor, aguarde ate o final.
echo.

set "PS1_URL=https://install.prosperarti.com.br/install.ps1"
set "PS1_LOCAL=%TEMP%\rd-prosperarti.ps1"

powershell -Command "[Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12; Invoke-WebRequest -Uri '%PS1_URL%' -OutFile '%PS1_LOCAL%' -UseBasicParsing"

if not exist "%PS1_LOCAL%" (
    echo.
    echo ERRO: nao foi possivel baixar o instalador.
    echo Verifique sua conexao com a internet e tente novamente.
    echo.
    pause
    exit /b 1
)

powershell -NoProfile -ExecutionPolicy Bypass -File "%PS1_LOCAL%"